- Tischtennisplatte

Tischtennisplatte

Die Platte besteht im wesentlichen aus einem Quader, einem Gestell aus Zylindern und dem eingefügtem Netz (Link).
Der Belag besteht aus einem weiteren dünnen, grünen Quader und weiteren weißen Quadern, die die Linien auf dem Tisch darstellen.

Quelltext:

// Deklaration Tisch
#declare Breite = 1.525;
#declare Laenge = 2.74;
#declare Belag = box {<0,0,0><Laenge,0.0001,Breite> texture {pigment {color Green}}}
// grüner Tischbelag
#declare Linie1 = box {<0,0,0><Laenge,0.0002,0.02> texture {pigment{color White}}}
// waagrechte lange Linie
#declare Linie2 = box {<0,0,0><0.02,0.0002,Breite>texture {pigment{color White}}}
// senkrechte kurze Linie
#declare Netzlinie = box {<0,0,0><0.02,0.0002,Breite>}
// Trennung der Tischhälften
#declare Platte = box {<0,0,0><2.74,-0.05,1.525> texture {pigment {color Black}}}
// Platte
#declare LinieMitte = box {<0,0,0><Laenge,0.0002,0.02/2> texture {pigment{color White}}}
// ---------------------------------------------------------------------NETZ
#declare Netzlatte = box{<0,-0.01,0><0.01,0.01,Breite+0.3*1.4>}
#declare Netzpfosten = box{<-0.006,0,-0.005><0.006,0.15,0.005>}

#declare netz=isosurface {
function{
    f_mesh1(
       x,y,z,
       0.30, // distance between neighboring threads in the x direction,
       0.30, // distance between neighboring threads in the z direction,
       0.15, // relative thickness in the x and z directions,
       0.05, // amplitude of the weaving effect,
       0.25 // relative thickness in the y direction
    )
}
contained_by {box {<-1,-1,-1>,<1,1,1>}}
threshold 0.01
max_gradient 8

texture{ pigment{ color rgb <0.65,0.45,0.25>}
          normal { bumps 0.15 scale 0.015}
          finish { diffuse 0.9 specular 0.2 }
           }
rotate<0,0,90>
scale 1/12}
// end of isosurface

#declare netz1 = union{
#local Nr = 0;        // start
#local EndNr = 12.166; // end
#while (Nr< EndNr)

   object{netz translate<0,0,Nr*0.15>}

#local Nr = Nr + 1; // next Nr
#end                 //end of loop
object {Netzlatte translate <-0.005,0.15/2,-0.15*0.5>}
object {Netzlatte translate <-0.005,-0.15/2,-0.15*0.5>}
object {Netzpfosten translate <0,-0.15/2,-0.16/2>}
object {Netzpfosten translate <0,-0.15/2,Breite+0.15*2+0.12/2>}
}

//end of union
// ---------------------------------------------------------------ENDE NETZ

// ----------------------------------------------------------------Gestell
#declare Aussenbein = cylinder {<0,0,0><0,0.76,0>0.015 finish {phong 0.7}}
#declare Innenbein = cylinder {<0,0,0><0,0.76,0>0.015 finish {phong 0.7}}
#declare Querstrebe = cylinder {<0,0,0><Laenge/2-0.15-0.2,0,0>0.015 finish {phong 0.7}}
#declare Rad = cylinder {<0,0.05,0><0,0.05,0.01>0.05 finish {phong 0.7}}
#declare Verbinder = box {<-0.15,0.30,0.015><0.15,0.5,-0.015> finish {phong 0.7}}
#declare Querverbinder = box {<-0.15,0.30,0.015><0.15,0.5,Breite-0.4> finish {phong 0.7}}

#declare Teilgestell = union{
object{Aussenbein translate <-1.15,0,0>}
object{Aussenbein translate <1.15,0,0>}
object{Innenbein translate <-0.15,0,0>}
object{Innenbein translate <0.15,0,0>}
object{Querstrebe translate <-1.15,0.4,0>}
object{Querstrebe translate <0.14,0.4,0>}
object{Verbinder}
object{Rad translate <-0.15,0,0>}
object{Rad translate <0.15,0,0>}
}
#declare Gestell = union{
object {Teilgestell}
object {Teilgestell translate <0,0,Breite-0.4>}
object {Querverbinder}
}
// -----------------------------------------------------------Ende Gestell
// Ende Deklaration Tisch

#declare Tisch = union{
object {Belag}
object {Linie1}                                                         // unten
object {Linie1 translate <0,0,Breite-0.02>}                // oben
object {Linie2}                                                         // links
object {Linie2 translate <Laenge-0.02,0,0>}               // rechts
object {LinieMitte translate <0,0,(Breite-0.02)/2>}    // mitte
object {Netzlinie translate <(Laenge-0.02)/2,0,0>}    // Trennung der Tischhälften
object {Platte}
object {netz1 translate <Laenge/2,0.075,-0.15>}
object {Gestell translate <Laenge/2,-0.81,0.2>}

}

object {Tisch translate <-Laenge/2,0,-Breite/2>}